'=======================================================================================
'
' AUTHOR: 	Ben Christian (www.benchristian.com)
'
' DATE: 	16/03/2006
'
' COMMENT: 	Forces replication to the specified servers 
'
'=======================================================================================

On Error Resume Next

'Create IE window for output
Set objExplorer = WScript.CreateObject("InternetExplorer.Application")
objExplorer.Navigate "about:blank"   
objExplorer.ToolBar = 0
objExplorer.StatusBar = 0
objExplorer.Width=350
objExplorer.Height = 700
objExplorer.Left = 0
objExplorer.Top = 0

Do While (objExplorer.Busy)
    Wscript.Sleep 200
Loop    
objExplorer.Visible = 1 


'Display Initial Text in IE
objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '3'><b>Scripted Replication</b></font><br><br>"


'Create IADSTools object
Dim comDLL
Set comDLL=Createobject("IADsTools.DCFunctions")
If Err.Number > 0 Then
	objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '2', color='#FF0000'>Error: You must install the Windows 2000 Server or Windows Server 2003 Support Tools Resource Kit to run this script...</font><br>"	 
	wscript.quit
End If


'Call the replication function for each server (list the server to replicate to first, then the the source server)

Call Replicate("server2","server1")
Call Replicate("server3","server2")

Call Wait(20)

Call Replicate("server4","server3")
Call Replicate("server5","server4")

Call Wait(20)

Call Replicate("server5","server4")
Call Replicate("server4","server3")
Call Replicate("server3","server2")

'Output that replication completed successfully for all servers
objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '2'><br>Replication for all servers completed successfully.</font><br>"


Function Replicate(strDestination,strSource)

	'Output starting replication	
	objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '2'>Starting replication from <b>" & strSource & "</b> to <b>" & strDestination & "</b>...</font><br>"
	

	'Start the replication
	Result=comDLL.ReplicaSync(cstr(strDestination),"dc=yourdomain,dc=com",cstr(strSource))

	'Output results depending on error result
	If result=0 then 
		objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', color='#008000', size = '2'><b>Completed</b></font><br><BR>"
	else 
		objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '2', color='#FF0000'>Failed.. Will not continue</font><br>"
		wscript.quit
	End If

End Function

Function Wait(Seconds)
	WaitTime = Seconds * 1000
	objExplorer.Document.Body.InnerHTML = objExplorer.Document.Body.InnerHTML & "<font face='arial', size = '2'>Wait " & Seconds & " seconds...</font><br><br>"
	wscript.sleep WaitTime
End Function